installation d'un logiciel de type .bin externe ubuntu sofware

Karl-ub · Le 26/12/2023, à 19:59

Bonsoir à tous et à toutes! J'espère que mon message vous trouve en forme.

J'ai besoin de votre aide pour installer le logiciel :BIOVIA_DS2024Client.bin, j'ai regardé les différents codes utilisés dans le forum mais, je reçois ce message à chaque fois:"./install_DSClient.sh: 76: Syntax error: redirection unexpected"
J'ai changé d'emplacement, du téléchargements au bureau mais je reçois toujours la même réponse.
Merci d'avance pour vos réponses et espérons qu'un code marche.

xubu1957 · Le 26/12/2023, à 20:09

Bonjour,

Tu l'as récupéré où, ce logiciel ?

Un lien pour nous éclairer ?

Commandes utilisées et messages d'erreurs à fournir, en te servant du Retour utilisable de commande.

nany · Le 26/12/2023, à 20:36

Bonjour,

xubu1957 a écrit :

Tu l'as récupéré où, ce logiciel ?
Un lien pour nous éclairer ?

Ici (faut donner un e-mail professionnel pour pouvoir télécharger).

J’ai trouvé des instructions pour DS2021 (ici, là ou là…), je pense que ça ne doit pas trop changer pour DS2024.

Karl-ub · Le 27/12/2023, à 03:44

C'est un logiciel de biologie moléculaire(DISCOVERY STUDIO VISUALIZER), généralement téléchargeable après avoir fourni des informations personnelles.
Voici le code et le résultat:

karl@karl-ub:~$ cd Bureau
karl@karl-ub:~/Bureau$ chmod u+x BIOVIA_DS2024Client.bin 
karl@karl-ub:~/Bureau$ ./BIOVIA_DS2024Client.bin 
Verifying archive integrity...  100%   All good.
Uncompressing 'DS Client and extracting files, please wait ......'  100%  
./install_DSClient.sh: 55: [[: not found
./install_DSClient.sh: 76: Syntax error: redirection unexpected

Voici le lien: https://discover.3ds.com/discovery-stud … r-download
Merci et bien à vous.

Dernière modification par Karl-ub (Le 27/12/2023, à 03:52)

nany · Le 27/12/2023, à 07:16

Bonjour,

Karl-ub a écrit :

karl@karl-ub:~/Bureau$ ./BIOVIA_DS2024Client.bin

Alors, dans les instructions que je cite plus haut, Il faut exécuter le bin avec de paramètres :

./BIOVIA_2021.DS2021.Client.bin --noexec --target ~/progs/BIOVIA2021

En adaptant à ton fichier, ça devrait être :

./BIOVIA_DS2024Client.bin --noexec --target ~/progs/BIOVIA2024

Mais la procédure ne s’arrête pas là. Il y a encore plusieurs commandes à faire pour procéder à l’installation.
Je t’invite donc à suivre les liens que j’ai mis au message #3 (plutôt le troisième qui est pour Ubuntu 22.04) pour suivre la procédure en adaptant probablement certaines commandes pour coller avec DS2024.

geole · Le 27/12/2023, à 12:45

Bonjour.
Je n'ai pas trouvé les pré-requis pour la version 2024

Karl-ub · Le 27/12/2023, à 15:18

nany a écrit :

Bonjour,

J’ai trouvé des instructions pour DS2021 (ici, là ou là…), je pense que ça ne doit pas trop changer pour DS2024.

J'ai essayé d'installer comme eux mais je me suis bloqué sur l'étape 16

karl@karl-ub:~/BIOVIA/LicensePack/etc$ ./lp_config
bash: ./lp_config: /bin/csh: bad interpreter: No such file or directory

Malheureusement sans cette étape, impossible de faire marché le logiciel.

nany · Le 27/12/2023, à 15:43

Donne le retour de :

cat ~/BIOVIA/LicensePack/etc/lp_config

Karl-ub · Le 27/12/2023, à 18:04

nany a écrit :

Donne le retour de :
cat ~/BIOVIA/LicensePack/etc/lp_config

karl@karl-ub:~/BIOVIA/LicensePack/etc$ cat ~/BIOVIA/LicensePack/etc/lp_config
#!/bin/csh -f
#  lp_config - script to configure the License Pack
#                  called from installer and config_license_pack

setenv LANG C

set returncode=0

set mode = "config"
set lic_pack_dir = ""

set returncode=0
#Evaluate command options
while ($#argv >= 1 )
   switch ($argv[1])
      case -r:
         shift
         set mode = "remove"
         breaksw
      case -p:
         if($#argv > 1) then #make sure a parameter for -p is entered
           shift
           set lic_pack_dir = "$argv[1]"
           shift
         else
          goto usage 
         endif 
         breaksw
      case -h:
	 goto usage
      default:
         echo "Invalid argument encountered"
         goto usage
         exit 1
   endsw
end

#Get location of this script to set BIOVIA_LIC_PACK_DIR directory
if ( $lic_pack_dir == "" ) then
   set this_script = $0
   set this_script_dir = `dirname ${this_script}`
   set lic_pack_dir = `(cd $this_script_dir ; cd .. ; pwd)`
endif

setenv BIOVIA_LIC_PACK_DIR ${lic_pack_dir}

unset this_script_dir
unset this_script


#Configure the configuration files with license pack path
set lp_cshrc_tmpl = "$lic_pack_dir/share/templates/lp_cshrc.tmpl"
set lp_cshrc_file = "$lic_pack_dir/etc/lp_cshrc"
set lp_profile_tmpl = "$lic_pack_dir/share/templates/lp_profile.tmpl"
set lp_profile_file = "$lic_pack_dir/etc/lp_profile"

if ($mode == "remove") then
   goto remove_config
endif

#Configure env setup files
if (-e $lp_cshrc_tmpl) then
   sed "s%_BIOVIA_LIC_PACK_DIR_PATH_%$lic_pack_dir%g" $lp_cshrc_tmpl > $lp_cshrc_file 
   source $lic_pack_dir/etc/lp_cshrc
else
   echo ""
   echo "ERROR: $lp_cshrc_tmpl does not exist."
   echo "BIOVIA License Pack $lp_cshrc_file could not be created."
   echo "This must be properly configured before using BIOVIA software."
   exit 1
endif

if (-e $lp_profile_tmpl) then
   sed "s%=_BIOVIA_LIC_PACK_DIR_PATH_%=$lic_pack_dir%g" $lp_profile_tmpl > $lp_profile_file
else
   echo ""
   echo "ERROR: $lp_profile_tmpl not found."
   exit 1
endif

#Configure LIC_CONFIG with defaults
if !(-e $lic_pack_dir/share/data/LIC_CONFIG) then
   cp  $lic_pack_dir/share/templates/LIC_CONFIG.tmpl $lic_pack_dir/share/data/LIC_CONFIG
endif


# create link from lp_version to previously used LicensePack.version_data name
# This link must be created in core config to allow old lp_setup installers to 
# work against a core-only installation
if (-e $lic_pack_dir/share/data/lp_version) then
   (cd $lic_pack_dir/share/data ; ln -fs lp_version LicensePack.version_data >&/dev/null)
endif

set plat_list = "irix linux solaris"
#
# turn msid and lmgrd suid bit on to allow lock file to be removed by anyone
# remove wish image (if it exists) from bin directory
#
foreach plat ($plat_list)
   #This is no longer needed since support for autostart has been dropped
   #chmod ug+s $lic_pack_dir/$plat/bin/msi >& /dev/null
   #chmod ug+s $lic_pack_dir/$plat/bin/lmgrd >& /dev/null

   # create links msi -> to msid
   #if (-e $lic_pack_dir/$plat/bin/msi && ! -e $lic_pack_dir/$plat/bin/msid) then
   #   (cd $lic_pack_dir/$plat/bin ; ln -fs msi msid)
   #endif
   #
   # create hard links to lmutil if they don't exist
   #
   if (-e $lic_pack_dir/$plat/bin/lmutil) then
      foreach util (lmpath lmdiag lmdown lmhostid lminstall lmremove lmreread lmstat lmswitchr lmswitch lmver lmnewlog)
         if !(-e $lic_pack_dir/$plat/bin/${util}) then
            ln -f $lic_pack_dir/$plat/bin/lmutil $lic_pack_dir/$plat/bin/${util}
         endif
      end
   endif
   #
   # create hard links to lp_util if they don't exist
   #
   #set lp_util exists flag
   set lp_util_flag = 0
   if ("$plat" == "linux") then
      if (-e $lic_pack_dir/$plat/bin/rt_bin/lp_util) then
         set lp_util_flag = 1
      endif
   else   
      if (-e $lic_pack_dir/$plat/bin/lp_util) then
         set lp_util_flag = 1
      endif
   endif
   
   if ($lp_util_flag) then
      foreach util (lp_admin lp_install lp_server lp_tester lp_status lp_request lp_temp_license lpver)
         if ("$plat" == "linux") then
            if !(-e $lic_pack_dir/$plat/bin/${util}) then
               ln -f $lic_pack_dir/$plat/bin/rt_bin/lp_util $lic_pack_dir/$plat/bin/${util}  >& /dev/null
            endif
         else
            if !(-e $lic_pack_dir/$plat/bin/${util}) then
               ln -f $lic_pack_dir/$plat/bin/lp_util $lic_pack_dir/$plat/bin/${util}  >& /dev/null
            endif
         endif
      end
      #These tools are suppored on linux only
      if("$plat" == "linux") then
        foreach linuxUtil (lp_diag lp_log_archiver lp_offline lp_usage_report vlfu)
           if !(-e $lic_pack_dir/$plat/bin/${linuxUtil}) then
              ln -f $lic_pack_dir/$plat/bin/rt_bin/lp_util $lic_pack_dir/$plat/bin/${linuxUtil} >& /dev/null
           endif
	end
      endif   
   endif
end

#Make sure license pack is writable by owner
#Removed this to avoid changing permissions to a license pack after an upgrade, see bug #05104dkq01
#chmod -R 755 $lic_pack_dir >& /dev/null

#Create Licenses folder if it doesn't exit
if ! (-e $lic_pack_dir/Licenses) then
   mkdir -p $lic_pack_dir/Licenses
endif

#Create Offline Folder and make read/writable by all
if (-e $lic_pack_dir/Licenses) then
   mkdir -p $lic_pack_dir/Licenses/Offline >& /dev/null
   chmod 777 $lic_pack_dir/Licenses/Offline >& /dev/null
endif

#Create Archive Folder
if (-e $lic_pack_dir/Logs) then
   mkdir -p $lic_pack_dir/Logs/Archive >& /dev/null
endif

#Make sure data directory is writable to allow for server insurance
#chmod 777 $lic_pack_dir/data
#if ($status) then
#   echo "Unable to chmod 777 $lic_pack_dir/data."
#   echo "Must be other-writable to enable Server Insurance."
#endif

#Make sure logs directory is writable by owner to allow for server autostart mechanism
#chmod 777 $lic_pack_dir/Logs

#Call adaptor configuration script if it exists
if (-e $lic_pack_dir/config/lp_adapter_config) then
   $lic_pack_dir/config/lp_adapter_config
endif

source $lic_pack_dir/etc/lp_cshrc

#Remove DAEMON path settings
set lic = $lic_pack_dir/Licenses/msi.lic
set update_path = ""
#set curr_opt = ""

#if (-e "$lic") then
#   set curr_opt = `grep "^DAEMON " $lic | awk '{print $4}'` 
#endif

grep "^DAEMON " $lic >& /dev/null
if (-e  "$lic" && !($status)) then
   set curr_path = `grep "^DAEMON " $lic | awk '{print $3}'`
   set curr_server = `grep "^SERVER " $lic`
   if ("$curr_path" != "$update_path") then
         #Edit DAEMON line with license pack path to msid
         cat $lic | sed -e \
         's@DAEMON msi .*/msid@DAEMON msi @'\ > $lic.tmp1
         mv -f $lic.tmp1 $lic >& /dev/null
         rm -rf $lic.tmp1
   endif

   #Remove options file path setting
   #if ("$curr_opt" != "") then
   #   #set update_opt = "$lic_pack_dir/Licenses/msi.opt"
   #   set update_opt = " "
   #   if ("$curr_opt" != "$update_opt") then
   #         cat $lic | sed -e 's@'"$curr_opt"'@'"$update_opt"'@' > $lic.tmp1
   #         mv -f $lic.tmp1 $lic >& /dev/null
   #   endif
   #endif

   #Correct reportlog file path in options file
   set optfile = "$lic_pack_dir/Licenses/msi.opt"
   if ( -e $optfile ) then
      set curr_rlog = `grep "^REPORTLOG " $optfile | awk '{print $2}' | sed 's/+//'`
      if ("$curr_rlog" != "") then
         set update_rlog = "$lic_pack_dir/Logs/msi.rl"
         if ("$curr_rlog" != "$update_rlog") then
              cat $optfile | sed -e 's@'"$curr_rlog"'@'"$update_rlog"'@' > $optfile.tmp1
               mv -f $optfile.tmp1 $optfile >& /dev/null
         endif
      endif
   endif
endif

#Finished with configuration, so exit
goto exit_config

#-------------------------------------------
#Begins remove configuration section
#-------------------------------------------
remove_config:

#echo "Removing BIOVIA License Pack configuration..."
if (-e  $lic_pack_dir/etc/lp_cshrc) then
   source $lic_pack_dir/etc/lp_cshrc
else
   goto remove_config_done
endif

# Remove lp_version link
if (-e $lic_pack_dir/share/data/LicensePack.version_data) then
   rm -rf $lic_pack_dir/share/data/LicensePack.version_data
endif


#Remove LIC_CONFIG if identical to template
#diff $lic_pack_dir/share/data/LIC_CONFIG $lic_pack_dir/share/templates/LIC_CONFIG.tmpl
#if !($status) then
#   rm -rf $lic_pack_dir/share/data/LIC_CONFIG >& /dev/null
#endif

#Remove LIC_CONFIG even if modified by end user
if ( -e $lic_pack_dir/share/data/LIC_CONFIG ) then
   rm -rf $lic_pack_dir/share/data/LIC_CONFIG >& /dev/null
endif

#Remove the configured files

if (-e $lp_cshrc_file) then
   rm -f $lp_cshrc_file >&/dev/null
endif
if (-e $lp_profile_file ) then
   rm -f $lp_profile_file >&/dev/null
endif

set plat_list = "irix linux aix tru64 solaris"
#
#  Remove msid link
#
foreach plat ($plat_list)
   #Remove links msi -> to msid
   #if (-e $lic_pack_dir/$plat/bin/msid) then
   #   (cd $lic_pack_dir/$plat/bin ; rm -f msid)
   #endif
   #
   # remove hard links to lmutil if they exist
   #
   foreach util (lmpath lmdiag lmdown lmhostid lminstall lmremove lmreread lmstat lmswitch lmswitchr lmver lmnewlog)
      if (-e $lic_pack_dir/$plat/bin/${util}) then
         rm -rf $lic_pack_dir/$plat/bin/${util} >& /dev/null
      endif
   end
   #
   # remove hard links to lp_util if they exist
   #
   foreach util (lp_admin lp_diag lp_install lp_server lpver lp_tester lp_status lp_request lp_temp_license lp_log_archiver lp_usage_report lp_offline vlfu)
      if (-e $lic_pack_dir/$plat/bin/${util}) then
         rm -rf $lic_pack_dir/$plat/bin/${util} >& /dev/null
      endif
   end
end

#Remove Licesnes and Logs directories if they are empty
rmdir $lic_pack_dir/Licenses/backup >& /dev/null
rmdir $lic_pack_dir/Licenses/Offline >& /dev/null
rmdir $lic_pack_dir/Licenses >& /dev/null
rmdir $lic_pack_dir/Logs >& /dev/null
rmdir $lic_pack_dir/Logs/Archive >& /dev/null

remove_config_done:

#Call adapter configuration script with remove argument if it exists
if (-e $lic_pack_dir/config/lp_adapter_config) then
   $lic_pack_dir/config/lp_adapter_config -r
endif


#-------------------------------------------
# Exit Program
#-------------------------------------------
exit_config:

exit 0

usage:
echo "Usage: lp_config [-r | -p | -h]"
echo "   Purpose:  Configure BIOVIA License Pack Installation"
echo "   -r:         remove configuration"
echo "   -p <path>:  override path to license pack"
exit $returncode
karl@karl-ub:~/BIOVIA/LicensePack/etc$

ça fait la même chose.

nany · Le 27/12/2023, à 18:28

Bien alors, pour commencer, installe tcsh :

sudo apt install tcsh

Ensuite, change « #!/bin/csh -f » en « #!/bin/tcsh » dans le fichier lp_config :

sed -i 's|/bin/csh -f|/bin/tcsh|' ~/BIOVIA/LicensePack/etc/lp_config

Puis reprends la procédure là où ça coinçait.

Karl-ub · Le 27/12/2023, à 19:33

nany a écrit :

Bien alors, pour commencer, installe tcsh :
sudo apt install tcsh
Ensuite, change « #!/bin/csh -f » en « #!/bin/tcsh » dans le fichier lp_config :
sed -i 's|/bin/csh -f|/bin/tcsh|' ~/BIOVIA/LicensePack/etc/lp_config
Puis reprends la procédure là où ça coinçait.

karl@karl-ub:~/BIOVIA/DiscoveryStudio2024/bin$ ./DiscoveryStudio2024
/home/karl/BIOVIA/DiscoveryStudio2024/bin/../lib/DiscoveryStudio2024-bin: error while loading shared libraries: libpng15.so.15: cannot open shared object file: No such file or directory

Ils disent qu'il est impossible d'ouvrir les objets partagés

geole · Le 27/12/2023, à 20:06

Regarde si elle est présente quelque part.

whereis libpng15.so.15

Sinon un lien de téléchargement
et un autre

Dernière modification par geole (Le 27/12/2023, à 20:15)

nany · Le 27/12/2023, à 20:57

Alors il faut aller sur http://sourceforge.net/projects/libpng/files/libpng15/ pour télécharger (dans ~/Téléchargements) la dernière version de libpng15 (1.5.30) au format tar.xz puis passer les commandes :

cd ~/Téléchargements

tar -xf libpng-1.5.30.tar.xz

cd libpng-1.5.30

./configure --prefix=/usr/local/libpng

make check

sudo make install

make check

cd

sudo ln -s /usr/local/libpng/lib/libpng15.so.15 /usr/lib/libpng15.so.15

cp -v /usr/local/libpng/lib/libpng15.so.15 ~/BIOVIA/DiscoveryStudio2024/lib

Et normalement DiscoveryStudio2024 devrait alors pouvoir se lancer sans encombre.

Source.

Karl-ub · Le 27/12/2023, à 22:39

nany a écrit :

Alors il faut aller sur http://sourceforge.net/projects/libpng/files/libpng15/ pour télécharger (dans ~/Téléchargements) la dernière version de libpng15 (1.5.30) au format tar.xz puis passer les commandes :
cd ~/Téléchargements
tar -xf libpng-1.5.30.tar.xz
cd libpng-1.5.30
./configure --prefix=/usr/local/libpng
make check
sudo make install
make check
cd
sudo ln -s /usr/local/libpng/lib/libpng15.so.15 /usr/lib/libpng15.so.15
cp -v /usr/local/libpng/lib/libpng15.so.15 ~/BIOVIA/DiscoveryStudio2024/lib
Et normalement DiscoveryStudio2024 devrait alors pouvoir se lancer sans encombre.
Source.

karl@karl-ub:~/Downloads/libpng-1.6.39$ ./configure --prefix=/usr/local/libpng
checking for a BSD-compatible install... /usr/bin/install -c
checking whether build environment is sane... yes
checking for a race-free mkdir -p... /usr/bin/mkdir -p
checking for gawk... no
checking for mawk... mawk
checking whether make sets $(MAKE)... yes
checking whether make supports nested variables... yes
checking whether to enable maintainer-specific portions of Makefiles... no
checking for gcc... no
checking for cc... no
checking for cl.exe... no
checking for clang... no
configure: error: in `/home/karl/Downloads/libpng-1.6.39':
configure: error: no acceptable C compiler found in $PATH
See `config.log' for more details
karl@karl-ub:~/Downloads/libpng-1.

Il y a une erreur dans le code

iznobe · Le 28/12/2023, à 00:10

Bonjour , ce n' est pas une ereur dans le code , c ' est une erreur dans la compilation du au fait qu ' il manque le programme pour compiler en C .

Passe cette commande :

sudo apt-get install build-essential

et recommence

nany · Le 28/12/2023, à 02:46

Bonjour,

Karl-ub a écrit :

karl@karl-ub:~/Downloads/libpng-1.6.39$

Là tu as téléchargé libpng16 (version 1.6.39), j’avais pourtant précisé de prendre la version 1.5.30.
Donc tant mieux que la compilation n’ait pas fonctionné car libpng16 est normalement déjà installée.
Alors recommence en prenant bien soin de télécharger la version 1.5.30.

Et effectivement il faut installer build-essential pour pouvoir compiler, j’avais oublié que ce n’est pas installé par défaut.

Dernière modification par nany (Le 28/12/2023, à 02:47)

Karl-ub · Le 29/12/2023, à 00:24

nany a écrit :

Bonjour,
Karl-ub a écrit :
karl@karl-ub:~/Downloads/libpng-1.6.39$
Là tu as téléchargé libpng16 (version 1.6.39), j’avais pourtant précisé de prendre la version 1.5.30.
Donc tant mieux que la compilation n’ait pas fonctionné car libpng16 est normalement déjà installée.
Alors recommence en prenant bien soin de télécharger la version 1.5.30.
Et effectivement il faut installer build-essential pour pouvoir compiler, j’avais oublié que ce n’est pas installé par défaut.

Bonsoir, j'espère que vous vous portez bien et désolé du retard.
Effectivement, j'ai essayé avec la version 1.5.30, ça donnait la même reponse. Je vais installer le programme de compilation comme l'a dit "Iznobe" et voir la suite.

Karl-ub · Le 30/12/2023, à 06:24

Bonjour à tous et à toutes !
J'espère que vous avez passé une superbe nuit.

Enfin, ça marche!

Je tiens à vous rémercier (Nany) pour votre temps et l'aide que vous m'avez apporté.
Grâce à vous, je vais pouvoir terminer le taf, merci encore.

Ubuntu-fr

Navigation

Liens de recherche

Annonce

#1 Le 26/12/2023, à 19:59

installation d'un logiciel de type .bin externe ubuntu sofware

#2 Le 26/12/2023, à 20:09

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#3 Le 26/12/2023, à 20:36

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#4 Le 27/12/2023, à 03:44

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#5 Le 27/12/2023, à 07:16

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#6 Le 27/12/2023, à 12:45

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#7 Le 27/12/2023, à 15:18

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#8 Le 27/12/2023, à 15:43

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#9 Le 27/12/2023, à 18:04

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#10 Le 27/12/2023, à 18:28

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#11 Le 27/12/2023, à 19:33

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#12 Le 27/12/2023, à 20:06

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#13 Le 27/12/2023, à 20:57

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#14 Le 27/12/2023, à 22:39

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#15 Le 28/12/2023, à 00:10

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#16 Le 28/12/2023, à 02:46

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#17 Le 29/12/2023, à 00:24

Re : installation d'un logiciel de type .bin externe ubuntu sofware

#18 Le 30/12/2023, à 06:24

Re : installation d'un logiciel de type .bin externe ubuntu sofware

Pied de page des forums